用Arduino单片机读取PCF8591模数转换器的模拟量并转化为数字输出

PCF8591是一款单芯片，单电源和低功耗8位CMOS数据采集设备。博文[1]对该产品已有介绍，此处不再赘述。但该博文是使用NVIDIA Jetson nano运行python读取输入PCF8591的模拟量的，读取的结果显示在屏幕上，或输出模拟量点亮灯。NVIDIA Jetson nano是一款类似树莓派的，安装操作系统的PC[2]，虽然性能强，但毕竟需要启动操作系统，功耗大，成本高[3]。关于单片机和复杂电脑的区别见[3]。本文用Arduino单片机的C++语言实现同样的读取模拟量的功能，但读取完后不输出模拟量，也不显示在屏幕上，而是产生8个数字输出（该模数转换器是8位的，也就是说支持的模拟量和输出的数据是0～255之间的整数，可用8个二进制位表示）。这样的做法，对于不支持模拟输入，只支持数字输入的PLC来说是有用的。

一、基本知识的简介

（一）I2C通信方式

I2C是一种串口通信方式，使用SCL和SDA两根线进行通讯。使用该通信方式的两个设备有主站和从站之分。主站启动通讯，发送从站地址，以及一个读/写比特。如果发出的比特是0，即写，那么主站就继续向从站发送数据；如果主站发出的读/写比特是1，即读，那么就是由从站向主站发送数据，主站读取数据。具体的通讯过程，见[4]。在该实验中，Arduino单片机是主站，PCF8591是从站。

（二）PCF8591的地址

PCF8591的地址有7位，其中前4位是1001，后三位分别由数字输入A0，A1，A2决定[5]。在该试验中，使用的PCF8591板缺少A0，A1，A2的引脚，所以其地址固定为1001000。

（三）PCF8591的控制字节

PCF8591的控制字节是主站向其发送的第一个字节数据，用于设定PCF8591的模拟量输出参数。控制字节的详细说明见[1]。简单地说，从高位起第1位是0；第2位表明PCF8591的模拟量输出是否激活，该实验由于是通过串口向Arduino输出模拟量的值，所以无需使用模拟量输出，故为0；第3-4位表明模拟输入的形式，这里用单端输入，不用差分输入，故为00；第5位是0；第6位不使用自动递增所以也是0；第7-8位决定用哪个模拟量输入（PCF8591总共有4个模拟量输入）。

PCF8591上有3个可调电阻，其中Input0针脚对应的是蓝白电位器（可用一字型螺丝刀转动从而调节电阻）；Input1针脚对应的是光敏电阻；Input2针脚对应的是热敏电阻。该模数转换器的内部电路大致如图所示：

该产品带一些短接帽，可以将Input?和AIN?连接起来。因此，可以通过调节电阻，控制PCF8591的模拟量输入。

二、Arduino程序

Arduino单片机通过I2C的通讯方式和PCF8591进行交互。这里需要使用Arduino里的Wire.h库。该库的详细说明见[6]。

（一）程序基本说明

由于本实验使用的Arduino板是UNO R3，SDA和SCL的针脚分别为A4和A5。

这里，PCF8591的地址在代码中是一个固定值PCF8591，值为0b1001000。

程序最终产生的8个数字输出，按从低位到高位排，分别对应Arduino板的针脚2，3，4，5，6，7，8，9。所以要将它们的模式均设为数字输出。Arduino的输出是推挽输出，即高电平输出。

Arduino和PCF8591的交互主要分为两部分：

第一部分，是写数据，即Arduino向PCF8591发送控制字节，设定模拟量输出参数。用Wire.beginTransmission(address)函数开始，这里发送的是地址，然后通过Wire.write(data)先令读/写比特为0，然后发送数据，即控制字节。这里，用蓝白电位器作为模拟输入，所以控制字节为00000000。

第二部分，是读数据，即Arduino先启动通讯，然后PCF8591向Arduino发送字节，即收到的模拟量值。用Wire.requestForm(address, byte number, stop bit)开始，发送地址，令读/写比特为1，然后接收指定长度的数据，并结束通讯。这里只需读一个字节即可，因为PCF8591发送的模拟量值只占1个字节。所以byte number=1，stop bit=1。然后用Wire.read()读取收到的数据。

为了方便调试，这里也把收到的数据发送到Serial串口中（UART串口），供电脑端查看。

最后，把数据转换为8个布尔变量。用二进制移位的方式[7]，以及逻辑运算的方式提取字节中的每一个比特，然后用其激活Arduino板的数字输出。

（二）程序代码和接线方式

代码如下：

#include <Wire.h>
/*
Here try: PCF8591 gets value from analog input, then Arduino reads from the PCF8591, and export to discrete output of Arduino
*/

int outputPins[] = {2,3,4,5,6,7,8,9};
bool ch1;
bool ch2;
byte controlMessage;
byte result;
#define PCF8591 0b1001000
void setup() {
    for (int i = 0; i<=7; i++){
      pinMode(outputPins[i], OUTPUT); //set pins to output
    }
  Wire.begin();
  Serial.begin(9600);
}

void loop() {
  Wire.beginTransmission(PCF8591);
  ch1 = false;
  ch2 = false;
  //ch1 f ch2 f: channel 0: adjust pan
  //ch1 f ch2 t: channel 1: light resistor
  //ch1 t ch2 f: channel 2: thermal resistor
  //ch1 t ch2 t: channel 3
  controlMessage = 0x00 + (byte)ch1 * 0b00000010 + (byte)ch2 * 0b00000001;
  Wire.write(controlMessage); //write control message first, then relaunch and enter read mode
  //Wire.beginTransmission(PCF8591);
  Wire.requestFrom(PCF8591, 1, true);
  result = Wire.read();
  Serial.print(result);
  Serial.print(' ');
  Wire.endTransmission();

  //Now I would like to convert the variable into digitals
  for (int i=0; i<=7; i++) // For each digit, i need to extract from result
    {
      byte mask = 0x01 << i;
      byte maskedResult = result & mask;
      bool resultThisBit = (bool)(maskedResult >> i);
      if (resultThisBit){
        digitalWrite(outputPins[i], HIGH);
      }
      else{
        digitalWrite(outputPins[i], LOW);
      }
    }
  
  
  delay(100);
}

接线方式如下：